Flex Примеры, Adobe Flex, Флекс

<?xml version="1.0" encoding="UTF-8" standalone="no"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" xmlns:local="*" >
	<mx:Script>
	<![CDATA[
		private var arr:Array = [
			{ rank: "1", place: "3", lead: "Van Amstel, Louis", follow: "Burke, Cheryl" },
			{ rank: "2", place: "1", lead: "Weise, David", follow: "Weise, Valentina" },
			{ rank: "3", place: "2", lead: "Roberts, Jonathan", follow: "Trebunskaya, Anna" }
		];
 
	]]>
	</mx:Script>
	<mx:Button />
	<local:DataGridWithShiftKey id="dg" initialize="dg.dataProvider=arr" editable="true">
		<local:columns>
			<mx:DataGridColumn dataField="rank" width="50" headerText="Rank" />
			<mx:DataGridColumn dataField="lead" width="160" headerText="Leader" itemEditor="DataGridMultiFieldEditor" editorDataField="fullName" />
			<mx:DataGridColumn dataField="follow" width="160" headerText="Follower" itemEditor="DataGridMultiFieldEditor" editorDataField="fullName" />
			<mx:DataGridColumn dataField="place" width="50" headerText="Place" />
		</local:columns>
	</local:DataGridWithShiftKey>
	<mx:Button />
</mx:Application>

package 
{
import flash.events.KeyboardEvent;
import mx.controls.DataGrid;
 
/** 
 *  Редактору со множеством полей необходимо состояние c SHIFT
 */
public class DataGridWithShiftKey extends DataGrid
{
 
	public function DataGridWithShiftKey()
	{
		super();
	}
 
	override protected function createChildren():void
	{
		super.createChildren();
		systemManager.addEventListener(KeyboardEvent.KEY_DOWN, shiftKeyHandler, true, 0, true);
	}
 
	private var _shiftKey:Boolean;
 
	public function get shiftKey():Boolean
	{
		return _shiftKey;
	}
 
	private function shiftKeyHandler(event:KeyboardEvent):void
	{
		_shiftKey = event.shiftKey;
	}
 
}
 
}

package 
{
import flash.events.FocusEvent;
import mx.controls.DataGrid;
import mx.controls.dataGridClasses.DataGridColumn;
import mx.controls.dataGridClasses.DataGridListData;
import mx.controls.listClasses.BaseListData;
import mx.controls.listClasses.IDropInListItemRenderer;
import mx.controls.listClasses.IListItemRenderer;
import mx.controls.listClasses.IDropInListItemRenderer;
import mx.controls.TextInput;
import mx.core.UIComponent;
import mx.managers.IFocusManagerComponent;
 
/** 
 *  Редактор с двумя полями для DataGrid
 */
public class DataGridMultiFieldEditor extends UIComponent implements IListItemRenderer, IDropInListItemRenderer, IFocusManagerComponent
{
 
	public function DataGridMultiFieldEditor()
	{
		super();
		addEventListener(FocusEvent.KEY_FOCUS_CHANGE, keyFocusChangeHandler);
	}
 
	private var dgOwner:DataGridWithShiftKey;
 
	private var firstNameEditor:TextInput;
	private var lastNameEditor:TextInput;
 
	public function get fullName():String
	{
		return lastNameEditor.text + ", " + firstNameEditor.text;
	}
 
	private var _data:Object;
 
	public function get data():Object
	{
		return _data;
	}
 
	public function set data(value:Object):void
	{
		_data = value;
		invalidateProperties();
	}
 
	private var _listData:BaseListData;
 
	public function get listData():BaseListData
	{
		return _listData;
	}
 
	public function set listData(value:BaseListData):void
	{
		_listData = value;
	}
 
	override public function setFocus():void
	{
		if (dgOwner.shiftKey)
			lastNameEditor.setFocus();
		else
			firstNameEditor.setFocus();
	}
 
	override protected function createChildren():void
	{
		super.createChildren();
 
        firstNameEditor = new TextInput();
		addChild(firstNameEditor);
        lastNameEditor = new TextInput();
		addChild(lastNameEditor);
	}
 
	override protected function commitProperties():void
	{
		dgOwner = owner as DataGridWithShiftKey;
 
		super.commitProperties();
 
		var dgColumn:DataGridColumn = dgOwner.columns[DataGridListData(listData).columnIndex];
		var fullName:String = data[dgColumn.dataField];
		var names:Array = fullName.split(", ");
 
		lastNameEditor.text = names[0];
		firstNameEditor.text = names[1];
	}
 
	override protected function updateDisplayList(w:Number, h:Number):void
	{
		super.updateDisplayList(w, h);
		firstNameEditor.move(0, 0);
		firstNameEditor.setActualSize(w / 2, h);
		lastNameEditor.move(w / 2, 0);
		lastNameEditor.setActualSize(w / 2, h);
	}
 
	private function keyFocusChangeHandler(event:FocusEvent):void
	{
		if (event.shiftKey)
		{
			if (lastNameEditor.contains(getFocus()))
			{
				event.preventDefault();
				firstNameEditor.setFocus();
			}
		}
		else
		{
			if (firstNameEditor.contains(getFocus()))
			{
				event.preventDefault();
				lastNameEditor.setFocus();
			}
		}
	}
}
 
}