//Установим слушателя события COLLECTION_CHANGE
dataGrid.addEventListener(mx.events.CollectionEvent.COLLECTION_CHANGE, onDataGridDataChange, false, 0, true);
 
private var currentSort:mx.collections.Sort;
 
private function onDataGridDataChange(evt:CollectionEvent):void
{
 
                //получим ссылку на данные
                var ac:ArrayCollection = dataGrid.dataProvider as ArrayCollection;
                //установим слушателя на событие изменения коллекции
                ac.addEventListener(CollectionEvent.COLLECTION_CHANGE, onCollectionChanged,false,0,true);
 
                //если сортировка была до изменения данных, установим ее
                if (currentSort != null)
                {
                    ac.sort = currentSort;
                    ac.refresh();
                }
 
}
 
private function onCollectionChanged(evt:CollectionEvent):void
{
 
	if (evt.kind == CollectionEventKind.REFRESH)
	{
		var ac:ArrayCollection = evt.currentTarget as ArrayCollection;
                       //запомним текущую сортировку
		currentSort = ac.sort;
 
	}
 
}

<?xml version="1.0" encoding="utf-8"?>
<mx:Application name="DataGrid_headerSeparatorSkin_test"
        xmlns:mx="http://www.adobe.com/2006/mxml"
        backgroundColor="white">
 
    <mx:DataGrid id="dataGrid"
            headerSeparatorSkin="mx.skins.ProgrammaticSkin">
        <mx:dataProvider>
            <mx:ArrayCollection>
                <mx:Object c1="1. One" c2="1. Two" c3="1. Three" />
                <mx:Object c1="2. One" c2="2. Two" c3="2. Three" />
                <mx:Object c1="3. One" c2="3. Two" c3="3. Three" />
                <mx:Object c1="4. One" c2="4. Two" c3="4. Three" />
                <mx:Object c1="5. One" c2="5. Two" c3="5. Three" />
                <mx:Object c1="6. One" c2="6. Two" c3="6. Three" />
            </mx:ArrayCollection>
        </mx:dataProvider>
    </mx:DataGrid>
 
</mx:Application>

<?xml version="1.0" encoding="utf-8"?>
<mx:Application name="DataGrid_headerSeparatorSkin_test"
        xmlns:mx="http://www.adobe.com/2006/mxml"
        backgroundColor="white">
 
    <mx:Script>
        <![CDATA[
            import mx.skins.ProgrammaticSkin;
 
            private function btn_click(evt:MouseEvent):void {
                dataGrid.setStyle("headerSeparatorSkin", ProgrammaticSkin);
            }
        ]]>
    </mx:Script>
 
    <mx:Button id="btn"
            label="Set header separator skin"
            click="btn_click(event);" />
 
    <mx:DataGrid id="dataGrid">
        <mx:dataProvider>
            <mx:ArrayCollection>
                <mx:Object c1="1. One" c2="1. Two" c3="1. Three" />
                <mx:Object c1="2. One" c2="2. Two" c3="2. Three" />
                <mx:Object c1="3. One" c2="3. Two" c3="3. Three" />
                <mx:Object c1="4. One" c2="4. Two" c3="4. Three" />
                <mx:Object c1="5. One" c2="5. Two" c3="5. Three" />
                <mx:Object c1="6. One" c2="6. Two" c3="6. Three" />
            </mx:ArrayCollection>
        </mx:dataProvider>
    </mx:DataGrid>
 
</mx:Application>

<?xml version="1.0" encoding="utf-8"?>
<mx:Application name="DataGrid_headerSeparatorSkin_test"
        xmlns:mx="http://www.adobe.com/2006/mxml"
        backgroundColor="white">
 
    <mx:Style>
        DataGrid {
            headerSeparatorSkin: ClassReference("mx.skins.ProgrammaticSkin");
        }
    </mx:Style>
 
    <mx:DataGrid id="dataGrid">
        <mx:dataProvider>
            <mx:ArrayCollection>
                <mx:Object c1="1. One" c2="1. Two" c3="1. Three" />
                <mx:Object c1="2. One" c2="2. Two" c3="2. Three" />
                <mx:Object c1="3. One" c2="3. Two" c3="3. Three" />
                <mx:Object c1="4. One" c2="4. Two" c3="4. Three" />
                <mx:Object c1="5. One" c2="5. Two" c3="5. Three" />
                <mx:Object c1="6. One" c2="6. Two" c3="6. Three" />
            </mx:ArrayCollection>
        </mx:dataProvider>
    </mx:DataGrid>
 
</mx:Application>

<?xml version="1.0" encoding="utf-8"?>
<mx:Application name="Alert_PopUpManager_removePopUp_test"
        xmlns:mx="http://www.adobe.com/2006/mxml"
        backgroundColor="white"
        initialize="init();">
 
    <mx:Script>
        <![CDATA[
            import mx.controls.Alert;
            import mx.events.CloseEvent;
            import mx.managers.PopUpManager;
 
            private var alrt:Alert;
            private var alrtTimer:Timer;
 
            private function init():void {
                alrtTimer = new Timer(5000, 1);
                alrtTimer.addEventListener(TimerEvent.TIMER_COMPLETE, removeAlert);
            }
 
            private function showAlert():void {
                alrt = Alert.show("I'm an Alert control and I will close in 5 seconds unless closed by a user.", "Self closing Alert", Alert.OK, this, alrt_close);
                alrtTimer.reset();
                alrtTimer.start();
            }
 
            private function alrt_close(evt:CloseEvent):void {
                alrtTimer.stop();
                lbl.text = "Closed by user.";
            }
 
            private function removeAlert(evt:TimerEvent):void {
                PopUpManager.removePopUp(alrt);
                lbl.text = "Removed by application.";
            }
        ]]>
    </mx:Script>
 
    <mx:Button label="Show Alert" click="showAlert();" />
    <mx:Label id="lbl" />
 
</mx:Application>

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"
        layout="vertical"
        verticalAlign="middle"
        backgroundColor="white"
        creationComplete="init();">
 
    <mx:Script>
        <![CDATA[
            import flash.net.FileReference;
            import mx.controls.Alert;
 
            private var fileRef:FileReference;
            private var urlReq:URLRequest;
 
            private function init():void {
                fileRef = new FileReference();
                fileRef.addEventListener(Event.SELECT, fileRef_select);
                fileRef.addEventListener(Event.COMPLETE, fileRef_complete);
                fileRef.addEventListener(IOErrorEvent.IO_ERROR, fileRef_ioError);
                fileRef.addEventListener(DataEvent.UPLOAD_COMPLETE_DATA, fileRef_uploadCompleteData);
 
                urlReq = new URLRequest();
                urlReq.url = "http://localhost/uploader.php";
            }
 
            private function fileRef_uploadCompleteData(evt:DataEvent):void {
                //Данные с сервера, остальное -дело техники
                trace(evt.data)
            }
 
            private function start():void {
                fileRef.browse();
            }
 
            private function fileRef_select(evt:Event):void {
                fileRef.upload(urlReq);
            }
 
            private function fileRef_complete(evt:Event):void {
                Alert.show(evt.toString(), evt.type);
            }
 
            private function fileRef_ioError(evt:IOErrorEvent):void {
                Alert.show(evt.text, evt.type);
            }
        ]]>
    </mx:Script>
 
    <mx:Button label="upload" click="Поехали();" />
</mx:Application>

package my.components
{
	import flash.events.MouseEvent;
	import flash.geom.Point;
	import mx.controls.DataGrid;
	import mx.controls.listClasses.IListItemRenderer;
	import mx.events.DataGridEvent;
 
	public class MyDataGrid extends DataGrid {
	    [Inspectable(category="General", enumeration="true,false", defaultValue="false")]
	    public var doubleClickStartEdit:Boolean = false;
	    private var displayableColumns:Array;
	    private var displayableColumnsToColumns:Array;
	    public function MyDataGrid() {
	    	super();
	    	addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler);
	    	addEventListener(MouseEvent.DOUBLE_CLICK, mouseDoubleClickHandler);
	    }
	    override protected function mouseUpHandler(event:MouseEvent):void {
	    	var tmpEditable:Boolean = this.editable;
	    	if(doubleClickStartEdit) {
	    		this.editable = false;	
	    	}
	    	super.mouseUpHandler(event);
	    	this.editable = tmpEditable;
	    }
	    override protected function mouseDoubleClickHandler(event:MouseEvent):void {
	        var dataGridEvent:DataGridEvent;
	        var r:IListItemRenderer;
	        var pos:Point;
 
	        r = mouseEventToItemRenderer(event);
 
	        super.mouseDoubleClickHandler(event);
 
	        if (r && r != itemEditorInstance) {
	            pos = itemRendererToIndices(r);
 
	            if (pos && pos.y >= 0 && editable && doubleClickStartEdit) {
	                if (displayableColumns[pos.x].editable) {
	                    dataGridEvent = new DataGridEvent(DataGridEvent.ITEM_EDIT_BEGINNING, false, true);
	                    dataGridEvent.columnIndex = displayableColumnsToColumns[pos.x];
	                    dataGridEvent.dataField = displayableColumns[pos.x].dataField;
	                    dataGridEvent.rowIndex = pos.y;
	                    dataGridEvent.itemRenderer = r;
	                    dispatchEvent(dataGridEvent);
	                }
	            }
	        }
	    }
	    override protected function updateDisplayList(unscaledWidth:Number,
	                                                  unscaledHeight:Number):void {
	    	super.updateDisplayList(unscaledWidth, unscaledHeight);
            	displayableColumns = new Array;
            	displayableColumnsToColumns = new Array;
            	var n:int = columns.length;
            	for (var i:int = 0; i < n; i++) {
                    if (columns[i].visible) {
                    	displayableColumns.push(columns[i]);
                    	displayableColumnsToColumns.push(i);
                    }
            	}
	    }
	}
}

<view:MyDataGrid doubleClickStartEdit="true" doubleClickEnabled="true"/>

<?xml version="1.0" encoding="utf-8"?>
<mx:Application name="HBox_resizeEffect_test"
        xmlns:mx="http://www.adobe.com/2006/mxml"
        layout="vertical"
        verticalAlign="middle"
        backgroundColor="white">
 
    <mx:HDividedBox id="hDividedBox"
            width="100%"
            height="100%">
        <mx:HBox id="hBox1"
                backgroundColor="haloGreen"
                resizeEffect="Resize"
                width="100%"
                height="100%" />
        <mx:HBox id="hBox2"
                backgroundColor="haloBlue"
                resizeEffect="Resize"
                width="100%"
                height="100%" />
    </mx:HDividedBox>
 
</mx:Application>

<?xml version="1.0" encoding="utf-8"?>
<mx:Application name="HBox_resizeEffect_test"
        xmlns:mx="http://www.adobe.com/2006/mxml"
        layout="vertical"
        verticalAlign="middle"
        backgroundColor="white">
 
    <mx:Style>
        HBox {
            resizeEffect: ClassReference("mx.effects.Resize");
        }
    </mx:Style>
 
    <mx:HDividedBox id="hDividedBox"
            width="100%"
            height="100%">
        <mx:HBox id="hBox1"
                backgroundColor="haloGreen"
                width="100%"
                height="100%" />
        <mx:HBox id="hBox2"
                backgroundColor="haloBlue"
                width="100%"
                height="100%" />
    </mx:HDividedBox>
 
</mx:Application>

<?xml version="1.0" encoding="utf-8"?>
<mx:Application name="HBox_resizeEffect_test"
        xmlns:mx="http://www.adobe.com/2006/mxml"
        layout="vertical"
        verticalAlign="middle"
        backgroundColor="white"
        initialize="init();">
 
    <mx:Script>
        <![CDATA[
            import mx.containers.HBox;
            import mx.containers.HDividedBox;
            import mx.effects.Resize;
 
            private var hBox1:HBox;
            private var hBox2:HBox;
            private var hDividedBox:HDividedBox;
 
            private function init():void {
                hBox1 = new HBox();
                hBox1.percentWidth = 100;
                hBox1.percentHeight = 100;
                hBox1.setStyle("backgroundColor", "haloGreen");
                hBox1.setStyle("resizeEffect", Resize);
 
                hBox2 = new HBox();
                hBox2.percentWidth = 100;
                hBox2.percentHeight = 100;
                hBox2.setStyle("backgroundColor", "haloBlue");
                hBox2.setStyle("resizeEffect", Resize);
 
                hDividedBox = new HDividedBox();
                hDividedBox.percentWidth = 100;
                hDividedBox.percentHeight = 100;
                hDividedBox.addChild(hBox1);
                hDividedBox.addChild(hBox2);
                addChild(hDividedBox);
            }
        ]]>
    </mx:Script>
 
</mx:Application>

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"
        layout="vertical"
        verticalAlign="middle"
        backgroundColor="white"
        creationComplete="init();">
 
    <mx:Script>
        <![CDATA[
            import mx.utils.Base64Decoder;
 
            private var base64Dec:Base64Decoder;
 
            private function init():void {
                var byteArr:ByteArray;
 
                base64Dec = new Base64Decoder();
                base64Dec.decode(logo);
 
                byteArr = base64Dec.toByteArray();
 
                img.load(byteArr);
            }
        ]]>
    </mx:Script>
 
    <mx:String id="logo" source="logo.txt" />
 
    <mx:Form width="100%" height="100%">
        <mx:FormItem label="image:">
            <mx:Image id="img" />
        </mx:FormItem>
        <mx:FormItem label="source:"
                width="100%"
                height="100%">
            <mx:TextArea id="textArea"
                    text="{logo}"
                    editable="false"
                    width="100%"
                    height="100%" />
        </mx:FormItem>
    </mx:Form>
 
</mx:Application>

<?xml version="1.0" encoding="utf-8"?>
<mx:Application name="Alert_creationCompleteEffect_test_2"
        xmlns:mx="http://www.adobe.com/2006/mxml"
        layout="vertical"
        verticalAlign="middle"
        backgroundColor="white">
 
    <mx:Script>
        <![CDATA[
            import mx.controls.Alert;
 
            [Embed("assets/iconCritical.png")]
            private var IconCritical:Class;
 
            private function showAlert():void {
                var message:String = "The quick brown fox jumped over the lazy dog.";
                var title:String = "Alert title";
                var a:Alert = Alert.show(message,
                            title,
                            Alert.OK,
                            null,
                            null,
                            IconCritical);
                a.status = Capabilities.version;
                a.isPopUp = false;
            }
        ]]>
    </mx:Script>
 
    <mx:Style>
        Alert {
            creationCompleteEffect: ding;
        }
    </mx:Style>
 
    <mx:SoundEffect id="ding"
            source="@Embed('assets/ding.mp3')"
            useDuration="false" /> 
 
    <mx:Button id="button"
            label="Launch Alert"
            click="showAlert();" />
 
</mx:Application>

<?xml version="1.0" encoding="utf-8"?>
<mx:Application name="Alert_creationCompleteEffect_test_2"
        xmlns:mx="http://www.adobe.com/2006/mxml"
        layout="vertical"
        verticalAlign="middle"
        backgroundColor="white"
        initialize="init();">
 
    <mx:Script>
        <![CDATA[
            import mx.effects.SoundEffect;
            import mx.controls.Alert;
 
            [Embed("assets/iconCritical.png")]
            private const IconCritical:Class;
 
            [Embed("assets/ding.mp3")]
            private const DingSoundEffect:Class;
 
            private var ding:SoundEffect;
 
            private function init():void {
                ding = new SoundEffect();
                ding.source = DingSoundEffect;
                ding.useDuration = false;
            }
 
            private function showAlert():void {
                var message:String = "The quick brown fox jumped over the lazy dog.";
                var title:String = "Alert title";
                var a:Alert = Alert.show(message,
                            title,
                            Alert.OK,
                            null,
                            null,
                            IconCritical);
                a.setStyle("creationCompleteEffect", ding);
                a.status = Capabilities.version;
                a.isPopUp = false;
            }
        ]]>
    </mx:Script>
 
    <mx:Button id="button"
            label="Launch Alert"
            click="showAlert();" />
 
</mx:Application>

<?xml version="1.0" encoding="utf-8"?>
<mx:Application name="Button_willTrigger_buttonDown_test"
        xmlns:mx="http://www.adobe.com/2006/mxml"
        layout="vertical"
        verticalAlign="middle"
        backgroundColor="white">
 
    <mx:Script>
        <![CDATA[
            import mx.controls.Alert;
            import mx.events.FlexEvent;
            import mx.utils.StringUtil;
 
            private function verify_click():void {
                var listener:Boolean = btn.hasEventListener(FlexEvent.BUTTON_DOWN);
                var trigger:Boolean = btn.willTrigger(FlexEvent.BUTTON_DOWN);
                var str:String = "hasEventListener() = {0}{1}willTrigger() = {2}";
                Alert.show(StringUtil.substitute(str, listener, "n", trigger));
            }
 
            private function addEventListener_click():void {
                btn.addEventListener(FlexEvent.BUTTON_DOWN, btn_buttonDown);
                verify_click();
            }
 
            private function removeEventListener_click():void {
                btn.removeEventListener(FlexEvent.BUTTON_DOWN, btn_buttonDown);
                verify_click();
            }
 
            private function btn_buttonDown(evt:FlexEvent):void {
                Alert.show(evt.type);
            }
        ]]>
    </mx:Script>
 
    <mx:ApplicationControlBar dock="true">
        <mx:Button label="Verify listeners"
                click="verify_click();" />
 
        <mx:Spacer width="100%" />
 
        <mx:Button label="addEventListener()"
                click="addEventListener_click();" />
        <mx:Button label="removeEventListener()"
                click="removeEventListener_click();" />
    </mx:ApplicationControlBar>
 
    <mx:Button id="btn" label="Button" />
 
</mx:Application>

<?xml version="1.0" encoding="UTF-8" standalone="no"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" xmlns:local="*" >
	<mx:Script>
	<![CDATA[
		private var arr:Array = [
			{ rank: "1", place: "3", lead: "Van Amstel, Louis", follow: "Burke, Cheryl" },
			{ rank: "2", place: "1", lead: "Weise, David", follow: "Weise, Valentina" },
			{ rank: "3", place: "2", lead: "Roberts, Jonathan", follow: "Trebunskaya, Anna" }
		];
 
	]]>
	</mx:Script>
	<mx:Button />
	<local:DataGridWithShiftKey id="dg" initialize="dg.dataProvider=arr" editable="true">
		<local:columns>
			<mx:DataGridColumn dataField="rank" width="50" headerText="Rank" />
			<mx:DataGridColumn dataField="lead" width="160" headerText="Leader" itemEditor="DataGridMultiFieldEditor" editorDataField="fullName" />
			<mx:DataGridColumn dataField="follow" width="160" headerText="Follower" itemEditor="DataGridMultiFieldEditor" editorDataField="fullName" />
			<mx:DataGridColumn dataField="place" width="50" headerText="Place" />
		</local:columns>
	</local:DataGridWithShiftKey>
	<mx:Button />
</mx:Application>

package 
{
import flash.events.KeyboardEvent;
import mx.controls.DataGrid;
 
/** 
 *  Редактору со множеством полей необходимо состояние c SHIFT
 */
public class DataGridWithShiftKey extends DataGrid
{
 
	public function DataGridWithShiftKey()
	{
		super();
	}
 
	override protected function createChildren():void
	{
		super.createChildren();
		systemManager.addEventListener(KeyboardEvent.KEY_DOWN, shiftKeyHandler, true, 0, true);
	}
 
	private var _shiftKey:Boolean;
 
	public function get shiftKey():Boolean
	{
		return _shiftKey;
	}
 
	private function shiftKeyHandler(event:KeyboardEvent):void
	{
		_shiftKey = event.shiftKey;
	}
 
}
 
}

package 
{
import flash.events.FocusEvent;
import mx.controls.DataGrid;
import mx.controls.dataGridClasses.DataGridColumn;
import mx.controls.dataGridClasses.DataGridListData;
import mx.controls.listClasses.BaseListData;
import mx.controls.listClasses.IDropInListItemRenderer;
import mx.controls.listClasses.IListItemRenderer;
import mx.controls.listClasses.IDropInListItemRenderer;
import mx.controls.TextInput;
import mx.core.UIComponent;
import mx.managers.IFocusManagerComponent;
 
/** 
 *  Редактор с двумя полями для DataGrid
 */
public class DataGridMultiFieldEditor extends UIComponent implements IListItemRenderer, IDropInListItemRenderer, IFocusManagerComponent
{
 
	public function DataGridMultiFieldEditor()
	{
		super();
		addEventListener(FocusEvent.KEY_FOCUS_CHANGE, keyFocusChangeHandler);
	}
 
	private var dgOwner:DataGridWithShiftKey;
 
	private var firstNameEditor:TextInput;
	private var lastNameEditor:TextInput;
 
	public function get fullName():String
	{
		return lastNameEditor.text + ", " + firstNameEditor.text;
	}
 
	private var _data:Object;
 
	public function get data():Object
	{
		return _data;
	}
 
	public function set data(value:Object):void
	{
		_data = value;
		invalidateProperties();
	}
 
	private var _listData:BaseListData;
 
	public function get listData():BaseListData
	{
		return _listData;
	}
 
	public function set listData(value:BaseListData):void
	{
		_listData = value;
	}
 
	override public function setFocus():void
	{
		if (dgOwner.shiftKey)
			lastNameEditor.setFocus();
		else
			firstNameEditor.setFocus();
	}
 
	override protected function createChildren():void
	{
		super.createChildren();
 
        firstNameEditor = new TextInput();
		addChild(firstNameEditor);
        lastNameEditor = new TextInput();
		addChild(lastNameEditor);
	}
 
	override protected function commitProperties():void
	{
		dgOwner = owner as DataGridWithShiftKey;
 
		super.commitProperties();
 
		var dgColumn:DataGridColumn = dgOwner.columns[DataGridListData(listData).columnIndex];
		var fullName:String = data[dgColumn.dataField];
		var names:Array = fullName.split(", ");
 
		lastNameEditor.text = names[0];
		firstNameEditor.text = names[1];
	}
 
	override protected function updateDisplayList(w:Number, h:Number):void
	{
		super.updateDisplayList(w, h);
		firstNameEditor.move(0, 0);
		firstNameEditor.setActualSize(w / 2, h);
		lastNameEditor.move(w / 2, 0);
		lastNameEditor.setActualSize(w / 2, h);
	}
 
	private function keyFocusChangeHandler(event:FocusEvent):void
	{
		if (event.shiftKey)
		{
			if (lastNameEditor.contains(getFocus()))
			{
				event.preventDefault();
				firstNameEditor.setFocus();
			}
		}
		else
		{
			if (firstNameEditor.contains(getFocus()))
			{
				event.preventDefault();
				lastNameEditor.setFocus();
			}
		}
	}
}
 
}